summaryrefslogtreecommitdiff
path: root/lib/res/styles/meson.build
blob: ea1fb2f1be5294404960133a544e6c8844b69c73 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
sassc = find_program('sassc')

styles = ['default', 'monokai-pro', 'teatime']
style_targets = []

common_inputs = files(
  'partials/_base.scss',
  'partials/_notification.scss',
  'partials/_panel.scss',
  'partials/_launcher.scss',
  'partials/_control-center.scss',
  '_common.scss',
)

foreach style : styles
  style_targets += custom_target(
    style + '.scss',
    input: [style + '.scss'] + common_inputs,
    output: style + '.css',
    command: [sassc, '-a', '-M', '-t', 'compact', '@INPUT0@', '@OUTPUT@'],
  )
endforeach

styles_resource = gnome.compile_resources(
  'styles-resource',
  'styles.gresource.xml',
  source_dir: [
    meson.current_build_dir(),
    meson.current_source_dir(),
  ],
  dependencies: style_targets,
  c_name: 'foobar_styles',
  export: true,
  extra_args: [ '--manual-register' ],
)